修改通达信公式:请大神把下面公式加上均线
发布网友
共2个回答
热心网友
{多彩K线-主图公式, 显示大阳\\大阴\\涨停\\跌停\\假阴\\假阳\\跳空\\大K线中点,适用于通达信 }
C_: CONST(C),COLORLIRED,POINTDOT;{现价线}
MA5:=MA(C,5);
MA5角度: ATAN((MA5/REF(MA5,1)-1)*100)*180/3.1416,NODRAW;
DRAWKLINE(H,O,L,C);{重绘K线}
RC1:=REF(C,1);
CS:=IF(C>=1,10000,100000);
C涨停10:=1.10*RC1-49/CS;{考虑到4舍5入}
C涨停5 :=1.05*RC1-49/CS;
C跌停10:=0.90*RC1+51/CS;
C跌停5 :=0.95*RC1+51/CS;
ST:=NAMELIKE('S') OR NAMELIKE('*S');
涨停:= IF(ST, C>=C涨停5, C>=C涨停10);
跌停:= IF(ST, C<=C跌停5, C<=C跌停10);
盘中涨停:=IF(ST, H>=C涨停5, H>=C涨停10);
盘中跌停:=IF(ST, L<=C跌停5, L<=C跌停10);
STICKLINE(盘中涨停,H,MAX(C,O),0,0),COLORMAGENTA;{涨停后回落}
STICKLINE(盘中跌停,L,MIN(C,O),0,0),COLORLICYAN;{跌停后回升}
大阳线:=C>O AND (C>=C涨停5 OR C>(1.05*O-51/CS) ) OR (C>1000 AND C>RC1*1.024);
STICKLINE(大阳线,O,C,1,0),COLOR0000BB;
大阴线:=C<O AND (C<=C跌停5 OR C<(0.95*O+49/CS) ) OR (C>1000 AND C<RC1*0.976);
STICKLINE(大阴线,O,C,1,0),COLORLIGREEN;
STICKLINE(涨停,O,C,1,0),COLORMAGENTA;
STICKLINE(跌停,O,C,1,0),COLORLICYAN;
假阴:=C<O AND C>REF(C,1);
STICKLINE(假阴,O,C,0,0),COLORRED;{假阴柱};
假阳:=C>O AND C<REF(C,1);
STICKLINE(假阳,O,C,0,0),COLORGREEN;{假阳柱};
大盘TJ:=PERIOD=5 AND NAMELIKE('上证指数')
AND (ABS((C-REF(C,1)))/REF(C,1)>=0.025 OR ABS(C-O)>=60);
STICKLINE(大盘TJ,(H+L)/2,(H+L)/2,2,0),COLORYELLOW;{显示大盘日线的60点大K线中值};
STICKLINE((大阳线 OR 大阴线 OR 涨停 OR 跌停)
AND BETWEEN(C,1,500),L+(H-L)/2,L+(H-L)/2,1,0),COLORYELLOW;{大K线画中点线};
MAA5:MA(C,5);
MAA10:MA(C,10);
MAA20:MA(C,20);
MAA30:MA(C,30);
MAA60:MA(C,60);
MAA120:MA(C,120);
热心网友
需要几条几日的均线？
